TEMPLATE = app
CONFIG += console c++1z
CONFIG -= app_bundle
CONFIG -= qt

SOURCES += \
    erosion.cpp \
    main.cpp \
    cmap.cpp \
    version.cpp \
    map.cpp \
    image.cpp \
    OlsenNoise.cpp

HEADERS += \
    cmap.h \
    cmap_1.h \
    contrib_cmaps.h \
	turbo_colormap.hpp \
    vnum.h \
    map.h \
    image.h \
    olsennoise.hpp

DISTFILES += \
    gcm.pc \
    cmap.inc \
	color_palettes.pc \
	params.dat \
	params2.dat

INCLUDEPATH += /mnt/Vers1/include

LIBS += -lstdc++fs -lpthread -L$$PWD/../libs/ -lFastNoiseSIMDd

QMAKE_CXXFLAGS += -fcoroutines-ts -std=c++17
QMAKE_CXXFLAGS += -Wall -Wextra -Wpedantic -pedantic-errors -Wshadow -Wno-missing-braces
QMAKE_CXXFLAGS += -Wno-return-std-move-in-c++11 -Wno-undef -Wno-padded
QMAKE_CXXFLAGS += -Wno-covered-switch-default -Wno-deprecated-copy -Wimplicit-fallthrough
QMAKE_CXXFLAGS += -msse3 -march=native

QMAKE_CXXFLAGS_DEBUG += -g -fstandalone-debug -D_DEBUG -fno-omit-frame-pointer
#QMAKE_CXXFLAGS_DEBUG += -g -D_DEBUG
QMAKE_CXXFLAGS_DEBUG += -fsanitize=address,undefined

QMAKE_CXXFLAGS_RELEASE += -flto

#QMAKE_LFLAGS += -stdlib=libc++ -lc++ -lc++abi -fuse-ld=lld
QMAKE_LFLAGS_DEBUG += -fsanitize=address,undefined
QMAKE_LFLAGS -= -ccc-gcc-name g++

QMAKE_LFLAGS_RELEASE += -flto

cmap_inc.target = $$PWD/gen/cmap.inc
cmap_inc.depends = gcm.pc
cmap_inc.commands = $$PWD/xd-kb -dcmap_inc -tchar $$PWD/gcm.pc $$cmap_inc.target

QMAKE_EXTRA_TARGETS += cmap_inc
PRE_TARGETDEPS += $$PWD/gen/cmap.inc

BUILDNO = $$quote($$system(../get_git_commit.sh))
DEFINES += N_COMMIT=\"$${BUILDNO}\"

VERSION = 0.1.0.$$BUILDNO

DEPENDPATH += $$PWD/../libs $$PWD/../FastNoiseSIMD